Example 1 : chiffre d'affaire d'un magasin

1. Sauvgarder le fichier suivant dans votre repectoire de travail.

    
   www.math.u-bordeaux1.fr/~hzhang/m2/st/magasin.txt
   

   Il s'agit d'une série réelle $X_t$ qui représente l'évolution mensuelle du chiffre d'affaires d'une grande surface, datée du Août 1977 au Juillet 1983.
   1. Tracer graphiquement cette série, que remarqez vous ?
   2. Tracer logarithme de cette série, que constatez vous ?
   3. Comment enlever la pérodicité afin de la rendre stationnaire ?
   Corrigé

    
   data magasin;
    infile 'C:\Documents and Settings\zhang\Mes documents\My SAS Files\tp5\magasin.txt';
    input ca;
    id +1;
   run;
   
   data magasin;
     set magasin;
     lca=log(ca);
     t=_n_;
   run;
   
   proc gplot data=magasin;
     symbol1 i=join;
     /* plot ca*t;*/
     plot lca*t;
   run;
   quit;
   

   

   On remarque que la série $\verb+ca+$ est périodique, l'examen du graphe révèle notamement, un mois de déembre deux fois plus élevé environ que la normale et un mois d'août de niveau très faible. La tendence est visiblement exponentielle et la saisonnalité présente un caractère explosif. Ces deux phénomènes laissent penser qu'il s'agit d'un modèle multiplicatif. Une transformation logarithmiques des données semble s'imposer. En fin pour enlever la saisonnalité, on propose de faire la difference $B^{12}$

   

2. On considère maintenant la série transformée définie par $(1-B^{12}) \log X_t$.
   1. Tester la stationnarité de cette série.
   2. Proposer un ou deux modèles ARMA(p,q) convenable pour la série $(1-B^{12}) \log X_t$.
   3. Estimer les parametres par la méthode de maximum de vraisemblance. Tracer ACF, PACF ainsi que IACF pour les résidus.

   Corrigé

    
   proc arima data=magasin;
      identify var=lca(12) stationarity=(DICKEY);run; 
   	/* On voit qu il est stationnaire */
      estimate p = (12) METHOD=ML plot;run; 
   	/* p=(12) n est pas la meme chose que p=12 
      forecast id=t lead=12 out=prevision; run;
   quit;
   

   Le processus $(1-B^{12}) \log X_t$ est stationnaire d'après test ADF, mais les corrélogramme ACF, PACF presentent une valeur significative sur lag=12. On propose alors un modèle suivant
   
   $$\bgroup\color{blue} (1-\phi B^{12}) (Z_t-\mu) = \varepsilon_t \egroup$$
   
   
   où $Z_t = (1-B^{12}) \log X_t$. C'est à dire le processus $Z_t$ est un AR(12). L'option plot permet de tracer ACF, PACF et IACF des residus.
   
   
   
   
   
   $$\bgroup\color{blue} \begin{array}{l} (1+0.45303 B^{12}) (Z_t... ...2150)\phantom{ B^{12}) (Z_t-} (0.0039644) \end{array} \egroup$$
   
   

   On peut aussi remplacer l'étape estimation par

    
      estimate q = (12) METHOD=ML plot;run;
   

   Dans ce cas on considère le modèle suivant
   
   $$\bgroup\color{blue} Z_t-\mu = (1-\theta)\varepsilon_t \egroup$$
   
   

3. Prévision à l'horizon $h=12$. Pour le processus $\log X_t$ et tracer graphiquement votre prévision avec intervalle de confiance.

   Corrigé

    
   proc arima data=magasin;
      identify var=lca(12) nlag=12 stationarity=(DICKEY);run; /* il est stationnaire */
      estimate p = (12) METHOD=ML plot;run;
      forecast id=t lead=12 out=prevision; run;
   quit;
   
   proc gplot data=prevision;
      symbol1 i=join v=star h=1 cv=black ci=black co=black w=1;
      symbol2 i=join v=none h=3 cv=green ci=green co=green w=2;
      symbol3 i=join v=none h=3 cv=red   ci=red   co=red   w=2;
      plot lca*t=1 forecast*t=2 (l95 u95)*t=3 /overlay ;
   run;
   quit;
   

   
4. Prévision à l'horizon $h=12$. Pour le processus d'origine $X_t$ et tracer graphiquement votre prévision avec intervalle de confiance en utilisant l'option href pour séparer les obseravtions et les prévisions.

   Corrigé Il faut transformer le processus $\log X_t$ en $X_t$.

    
   data resultat;
    set prevision;
    ca = exp(lca);
    ca_forecast=exp(forecast);
    ca_l95=exp(l95);
    ca_u95=exp(u95);
   run;
   
   proc gplot data=resultat;
     symbol1 i=join v=star h=1 cv=black ci=black co=black w=1;
      symbol2 i=join v=none h=3 cv=green ci=green co=green w=2;
      symbol3 i=join v=none h=3 cv=red   ci=red   co=red   w=2;
      plot ca*t=1 ca_forecast*t=2 (ca_l95 ca_u95)*t=3 /overlay href=72;
   run;
   quit;