Example 3 : Air line passagers

Sauvgarder le fichier suivant dans votre repectoire de travail.

 
www.math.u-bordeaux1.fr/~hzhang/m2/st/airline.txt

La série représente le nombre de passagers mensuelle pendant 12 précedentes années, calculer la prévision des passagers pour l'année suivante.

Corrigé

On peut trouver cet example dans

 
http://support.sas.com/onlinedoc/913/docMainpage.jsp

dans la partie ETS procedure ARIMA

Example 11.2: Seasonal Model for the Airline Series

 
title1 'International Airline Passengers'; 
   title2 '(Box and Jenkins Series-G)'; 
   data seriesg; 
      input x @@; 
      xlog = log( x ); 
      date = intnx( 'month', '31dec1948'd, _n_ ); 
      format date monyy.; 
      datalines; 
   112 118 132 129 121 135 148 148 136 119 104 118 
   115 126 141 135 125 149 170 170 158 133 114 140 
   145 150 178 163 172 178 199 199 184 162 146 166 
   171 180 193 181 183 218 230 242 209 191 172 194 
   196 196 236 235 229 243 264 272 237 211 180 201 
   204 188 235 227 234 264 302 293 259 229 203 229 
   242 233 267 269 270 315 364 347 312 274 237 278 
   284 277 317 313 318 374 413 405 355 306 271 306 
   315 301 356 348 355 422 465 467 404 347 305 336 
   340 318 362 348 363 435 491 505 404 359 310 337 
   360 342 406 396 420 472 548 559 463 407 362 405 
   417 391 419 461 472 535 622 606 508 461 390 432 
   ; 
    
   symbol1 i=join  v=dot; 
   proc gplot data=seriesg; 
      plot x * date = 1 / haxis= '1jan49'd to '1jan61'd by year; 
   run;

 
   proc arima data=seriesg; 
      identify var=xlog(1,12) nlag=15; 
      run; 
      estimate q=(1)(12) noconstant method=uls; 
      run; 
      forecast out=b lead=24 id=date interval=month noprint; 
   quit;

data c; 
      set b; 
      x        = exp( xlog ); 
      forecast = exp( forecast + std*std/2 ); 
      l95      = exp( l95 ); 
      u95      = exp( u95 ); 
   run;


 symbol1 i=none  v=star; 
   symbol2 i=join  v=circle; 
   symbol3 i=join  v=none l=3; 
   proc gplot data=c; 
      where date >= '1jan58'd; 
      plot x * date = 1 forecast * date = 2 
           l95 * date = 3 u95 * date = 3 / 
           overlay haxis= '1jan58'd to '1jan62'd by year; 
   run;

Ici, on a donné le model final. Biensur, pour arriver fixer c e modele final, il faut faire le travail de transformation, identification, estimation, etc.